104 lines
2 KiB
Plaintext
104 lines
2 KiB
Plaintext
|
/* Linker script for SolarLader: STM32F0K6T6*/
|
||
|
|
|
||
|
|
/* This debug linker script places everything in RAM for fewer flash write
|
||
|
|
* cycles */
|
||
|
|
|
||
|
|
/* Define memory regions. */
|
||
|
|
MEMORY
|
||
|
|
{
|
||
|
|
/*rom (rx) : ORIGIN = 0x08000000, LENGTH = 64K*/
|
||
|
|
ram (rwx) : ORIGIN = 0x20000000, LENGTH = 4K
|
||
|
|
}
|
||
|
|
|
||
|
|
/* Include the common ld script. */
|
||
|
|
/* INCLUDE libopencm3_stm32f4.ld */
|
||
|
|
|
||
|
|
|
||
|
|
/* Generic linker script for STM32 targets using libopencm3. */
|
||
|
|
|
||
|
|
/* Memory regions must be defined in the ld script which includes this one. */
|
||
|
|
|
||
|
|
/* Enforce emmition of the vector table. */
|
||
|
|
EXTERN (vector_table)
|
||
|
|
|
||
|
|
/* Define the entry point of the output file. */
|
||
|
|
ENTRY(reset_handler)
|
||
|
|
|
||
|
|
/* Define sections. */
|
||
|
|
SECTIONS
|
||
|
|
{
|
||
|
|
.text : {
|
||
|
|
*(.vectors) /* Vector table */
|
||
|
|
*(.text*) /* Program code */
|
||
|
|
. = ALIGN(4);
|
||
|
|
*(.rodata*) /* Read-only data */
|
||
|
|
. = ALIGN(4);
|
||
|
|
} >ram
|
||
|
|
|
||
|
|
/* C++ Static constructors/destructors, also used for __attribute__
|
||
|
|
* ((constructor)) and the likes */
|
||
|
|
.preinit_array : {
|
||
|
|
. = ALIGN(4);
|
||
|
|
__preinit_array_start = .;
|
||
|
|
KEEP (*(.preinit_array))
|
||
|
|
__preinit_array_end = .;
|
||
|
|
} >ram
|
||
|
|
.init_array : {
|
||
|
|
. = ALIGN(4);
|
||
|
|
__init_array_start = .;
|
||
|
|
KEEP (*(SORT(.init_array.*)))
|
||
|
|
KEEP (*(.init_array))
|
||
|
|
__init_array_end = .;
|
||
|
|
} >ram
|
||
|
|
.fini_array : {
|
||
|
|
. = ALIGN(4);
|
||
|
|
__fini_array_start = .;
|
||
|
|
KEEP (*(.fini_array))
|
||
|
|
KEEP (*(SORT(.fini_array.*)))
|
||
|
|
__fini_array_end = .;
|
||
|
|
} >ram
|
||
|
|
|
||
|
|
/*
|
||
|
|
* Another section used by C++ stuff, appears when using newlib with
|
||
|
|
* 64bit (long long) printf support
|
||
|
|
*/
|
||
|
|
.ARM.extab : {
|
||
|
|
*(.ARM.extab*)
|
||
|
|
} >ram
|
||
|
|
.ARM.exidx : {
|
||
|
|
__exidx_start = .;
|
||
|
|
*(.ARM.exidx*)
|
||
|
|
__exidx_end = .;
|
||
|
|
} >ram
|
||
|
|
|
||
|
|
. = ALIGN(4);
|
||
|
|
_etext = .;
|
||
|
|
|
||
|
|
.data : {
|
||
|
|
_data = .;
|
||
|
|
*(.data*) /* Read-write initialized data */
|
||
|
|
. = ALIGN(4);
|
||
|
|
_edata = .;
|
||
|
|
} >ram
|
||
|
|
|
||
|
|
.bss : {
|
||
|
|
*(.bss*) /* Read-write zero initialized data */
|
||
|
|
*(COMMON)
|
||
|
|
. = ALIGN(4);
|
||
|
|
_ebss = .;
|
||
|
|
} >ram
|
||
|
|
|
||
|
|
/*
|
||
|
|
* The .eh_frame section appears to be used for C++ exception handling.
|
||
|
|
* You may need to fix this if you're using C++.
|
||
|
|
*/
|
||
|
|
/DISCARD/ : { *(.eh_frame) }
|
||
|
|
|
||
|
|
. = ALIGN(4);
|
||
|
|
end = .;
|
||
|
|
}
|
||
|
|
|
||
|
|
PROVIDE(_stack = ORIGIN(ram) + LENGTH(ram));
|
||
|
|
|
||
|
|
|